Ficheiro:Hyperbolic orbit.gif

O conteúdo da página não é suportado noutras línguas.
Origem: Wikipédia, a enciclopédia livre.

Hyperbolic_orbit.gif ‎(300 × 300 píxeis, tamanho: 12 kB, tipo MIME: image/gif, cíclico, 90 quadros, 4,2 s)

 
Este(a) gráfico foi criado com o Persistence of Vision.
a Semimajor axis
rp Periapsis' Radius
υ∞ Divergence angle

Descrição do ficheiro

Descrição Animation showing the motion of a small body (green) in an hyperbolic orbit around a much more massive body (blue).
Data
Origem Own work. Rendered with PovRay-3.0, animated with gifsicle.
Autor Brandir
Permissão
(Reutilizar este ficheiro)		 Brandir put it under the GFCL and the CC-BY-SA

Licenciamento

Eu, titular dos direitos de autor desta obra, publico-a com as seguintes licenças:
GNU head É concedida permissão para copiar, distribuir e/ou modificar este documento nos termos da Licença de Documentação Livre GNU, versão 1.2 ou qualquer versão posterior publicada pela Free Software Foundation; sem Secções Invariantes, sem textos de Capa e sem textos de Contra-Capa. É incluída uma cópia da licença na secção intitulada GNU Free Documentation License.
w:pt:Creative Commons
atribuição partilha nos termos da mesma licença 		A utilização deste ficheiro é regulada nos termos da licença Creative Commons - Atribuição-CompartilhaIgual 3.0 Não Adaptada.
Pode:
  • partilhar – copiar, distribuir e transmitir a obra
  • recombinar – criar obras derivadas
De acordo com as seguintes condições:
  • atribuição – Tem de fazer a devida atribuição da autoria, fornecer uma hiperligação para a licença e indicar se foram feitas alterações. Pode fazê-lo de qualquer forma razoável, mas não de forma a sugerir que o licenciador o apoia ou subscreve o seu uso da obra.
  • partilha nos termos da mesma licença – Se remisturar, transformar ou ampliar o conteúdo, tem de distribuir as suas contribuições com a mesma licença ou uma licença compatível com a original.
Esta marca de licenciamento foi adicionada a este ficheiro durante a atualização da licença GFDL.
w:pt:Creative Commons
atribuição partilha nos termos da mesma licença
A utilização deste ficheiro é regulada nos termos da licença Creative Commons - Atribuição-CompartilhaIgual 2.5 Espanha.
Pode:
  • partilhar – copiar, distribuir e transmitir a obra
  • recombinar – criar obras derivadas
De acordo com as seguintes condições:
  • atribuição – Tem de fazer a devida atribuição da autoria, fornecer uma hiperligação para a licença e indicar se foram feitas alterações. Pode fazê-lo de qualquer forma razoável, mas não de forma a sugerir que o licenciador o apoia ou subscreve o seu uso da obra.
  • partilha nos termos da mesma licença – Se remisturar, transformar ou ampliar o conteúdo, tem de distribuir as suas contribuições com a mesma licença ou uma licença compatível com a original.
Pode escolher a licença que quiser.

POV-Ray Scene description

POV-ray image description: 

 /*
 --------------------------
 Hyperbolic Orbit Animation
 --------------------------
 Created 7 Mar. 2006
 */
     
 #include "colors.inc"
 
 //Orbit Definition
 #declare OrbitA=30;
 #declare OrbitE=1.38;
 
 //Scene Constants
 #declare EarthRadius=6.356;
 #declare SatRadius=1.2;
 #declare OrbitWidth=0.5;
 #declare LineWidth=0.5/3;
 #declare Crosslength=1.5;
 #declare Textscale=9;
 #declare TextColor=rgb<0,0,0>;
 #declare xinit=-35;
 
 //Variables
 #declare Minit=OrbitE*sinh(acosh(-(xinit/OrbitA-OrbitE)))-acosh(-(xinit/OrbitA-OrbitE));
 #declare M=Minit-2*clock*Minit;
 #declare PI=3.14159265359;
 #declare Angleinf=180-acos(-1/OrbitE)*(180/PI);
 
 //Anomaly Determination - Solves the equation M=e*sinh(H)-H by the iterative method
 #declare Index=0;
 #declare prevAnomaly=0;
 #declare Anomaly=0;
 #while (Index<30)
     #declare Anomaly=asinh((M+prevAnomaly)/OrbitE);
     #declare prevAnomaly=Anomaly;
     #declare Index=Index+1;
 #end
 
 //General settings
 global_settings{
     ambient_light 1
     }
 
 light_source { <-50, 0, -70> color White }
 
 camera {
   orthographic
   location <-10, 0, -10>
   look_at  <-10, 0,  0>
   up <0,100,0>
   right <100,0,0>
 }
 
 
 plane { <0, 0, 1>, 8
     pigment {White}
     finish{ambient 1 brilliance 0}
 }
 
 
 //Earth
 sphere {
     <0, 0, 0>, EarthRadius
     pigment { Blue }
     finish{ ambient 0.3 brilliance 1.2 diffuse 0.8}
 }
 
 
 //Orbit
 intersection{
     box{
         <-100,-100,-OrbitWidth>, <100,100,OrbitWidth> 
     }
     quadric{
         <1/(OrbitA*OrbitA),-1/(OrbitA*OrbitA*(OrbitE*OrbitE-1)),0>,<0,0,0>,<2*OrbitE/OrbitA,0,0>,OrbitE*OrbitE-1
         translate x*OrbitWidth/2
     }
     quadric{
         <-1/(OrbitA*OrbitA),1/(OrbitA*OrbitA*(OrbitE*OrbitE-1)),0>,<0,0,0>,<-2*OrbitE/OrbitA,0,0>,1-OrbitE*OrbitE
         translate -x*OrbitWidth/2
     }
     pigment{ rgb<0.8,0,0> }
     finish{ ambient 1 brilliance 0 diffuse 0}
     rotate 2.2*y
     no_shadow
 }
 
 
 //Satellite
 sphere {
     <0, 0, -10>, SatRadius
     pigment { SeaGreen }
     finish{ ambient 1 brilliance 0 diffuse 0}
     no_shadow
     translate <-OrbitA*(OrbitE-cosh(Anomaly)),OrbitA*sqrt(OrbitE*OrbitE-1)*sinh(Anomaly),0>
 }
 
 //Lines
 #declare crossBars=
 object{
     union{
         box{
             <-LineWidth,-Crosslength,-LineWidth-7>, <LineWidth,Crosslength,LineWidth-7> 
         }
         box{
             <-Crosslength,-LineWidth,-LineWidth-7>, <Crosslength,LineWidth,LineWidth-7>
         }
         rotate z*45
         pigment{ TextColor }
         finish{ ambient 1 brilliance 0 diffuse 0}
         no_shadow
     }
 }
 
 box{
     <-OrbitA*OrbitE-3,-LineWidth,-LineWidth-7>, <0,LineWidth,LineWidth-7> 
     pigment{ TextColor }
     finish{ ambient 1 brilliance 0 diffuse 0}
     no_shadow
 }
 
 box{
     <0,-LineWidth,-LineWidth-7>, <300,LineWidth,LineWidth-7> 
     pigment{ TextColor }
     finish{ ambient 1 brilliance 0 diffuse 0}
     rotate z*Angleinf
     translate -x*OrbitA*OrbitE
     no_shadow
 }
 
 box{
     <0,-LineWidth,-LineWidth-7>, <300,LineWidth,LineWidth-7> 
     pigment{ TextColor }
     finish{ ambient 1 brilliance 0 diffuse 0}
     rotate -z*Angleinf
     translate -x*OrbitA*OrbitE
     no_shadow
 }
 
 difference{
     torus{
         4,LineWidth
         rotate x*90
     }
     box {
         <-5,0,-5>,<5,5,5>
     }
     box {
         <-5,-5,-5>,<5,0,5>
         rotate -z*Angleinf
     }
     pigment{ TextColor }
     finish{ ambient 1 brilliance 0 diffuse 0}
     translate -z*7
     translate -x*OrbitA*OrbitE
     no_shadow
 }
 
 object{
     crossBars
 }
 
 object{
     crossBars
     translate -x*OrbitA*(OrbitE-1)
 }
 
 object{
     crossBars
     translate -x*OrbitA*OrbitE
 }
 
 //Text
 text {
     ttf "timesi.ttf" "a" 1, 0
     pigment{ TextColor }
     finish{ ambient 1 brilliance 0 diffuse 0}
     scale Textscale
     translate <OrbitA*(0.5-OrbitE)-Textscale/4,Textscale/4,-7>
     no_shadow
 }
 
 union{
     text {
         ttf "timesi.ttf" "r" 1, 0
     }
     text {
         ttf "timesi.ttf" "p" 1, 0
         scale 0.5
         translate 0.2*x
     }
     pigment{ TextColor }
     finish{ ambient 1 brilliance 0 diffuse 0}
     scale Textscale
     translate <-(EarthRadius+0.3*(OrbitA*(OrbitE-1)-EarthRadius))-Textscale/4,Textscale/4,-7>
     no_shadow
 }
 
 union{
     text {
         ttf "symbol.ttf" "u" 1, 0
         matrix 
             < 1, 0, 0,
             0.3, 1, 0,
             0, 0, 1,
             0, 0, 0 >
     }
     text {
         ttf "symbol.ttf" chr(165) 1, 0
         scale 0.5
         translate <0.6,-0.1,0>
     }
     pigment{ TextColor }
     finish{ ambient 1 brilliance 0 diffuse 0}
     scale Textscale
     translate <-OrbitA*OrbitE-Textscale/4+9,-0.6*Textscale,-7>
     no_shadow
 }

Legendas

Adicione uma explicação de uma linha do que este ficheiro representa

Elementos retratados neste ficheiro

retrata

Histórico do ficheiro

Clique uma data e hora para ver o ficheiro tal como ele se encontrava nessa altura.

Data e horaMiniaturaDimensõesUtilizadorComentário
atual00h01min de 8 de março de 2006Miniatura da versão das 00h01min de 8 de março de 2006300 × 300 (12 kB)Brandir~commonswiki{{Information| |Description = Animation showing the motion of a small body (green) in an hyperbolic orbit around a much more massive body (blue). |Source = Own work. Rendered with ''PovRay-3.0'', animated with ''gifsicle''. |Date = Created 7. Mar. 2006.

Não há nenhuma página que use este ficheiro.

Utilização global do ficheiro

Obtida de "https://pt.wikipedia.org/wiki/Ficheiro:Hyperbolic_orbit.gif"