Wikipédia:GLAM/Museu Paulista/Acervo/Queries

Queries

É possível encontrar acima o link para diversas listas do acervo desta iniciativa GLAM. Mas afinal, como eles são gerados? No contexto do uso de bancos de dados, uma query pode remeter a um comando de consulta às informações nele presentes. A título de exemplo, o comando SELECT NOME, SOBRENOME FROM USUARIOS WHERE RG=55.555.555-55 retornaria como resposta o NOME e o SOBRENOME da tabela USUARIOS, do cadastro que possui o RG 55.555.555-55'. Assim, considerando que os dados presentes nesta iniciativa GLAM estão estruturados no Wikidata, que é um banco de dados e que possui uma interface de comandos de queries que pode ser acessada aqui, é possível buscar informações de maneira única e versátil, cruzando dados e gerando visualizações que permitem ter uma dimensão mais apurada do banco de dados em questão.

Gráfico de bolhas de instâncias das obras do acervo

O código abaixo gera um gráfico de bolhas sobre as instâncias das obras da coleção Museu Paulista.

#defaultView:BubbleChart
SELECT ?q ?qLabel (COUNT(?q) as ?soma) WHERE {
    ?item wdt:P195 wd:Q56677470.
    ?item wdt:P31 ?q .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]". }
    FILTER NOT EXISTS { ?item wdt:P31 wd:Q18593264 }
} 
GROUP BY ?q ?qLabel
ORDER BY DESC (?soma)
LIMIT 50

Experimente!

Gráfico de bolhas da quantidade de obras no acervo, por artista

O código abaixo gera um gráfico de bolhas sobre os criadores das obras da coleção Museu Paulista, excluindo o fotógrafo Militão Augusto de Azevedo.

#defaultView:BubbleChart
SELECT ?q ?qLabel (COUNT(?q) AS ?soma) WHERE {
  ?item wdt:P195 wd:Q56677470.
  ?item wdt:P170 ?q.
  FILTER(NOT EXISTS { ?item wdt:P170 wd:Q4233718. })
  FILTER(NOT EXISTS { ?item wdt:P170 wd:Q10330043. })
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]". }
}
GROUP BY ?q ?qLabel
ORDER BY DESC (?soma)
LIMIT 100

Experimente!

Mapa dos locais de nascimento dos artistas do acervo

O código abaixo gera um mapa dos locais de nascimento dos artistas que mais contribuíram com o acervo do Museu Paulista.

#defaultView:Map
# Show place of birth locations for most prominent artists
SELECT DISTINCT ?q ?qLabel ?nascLabel ?coord ?img WHERE
{
  {
    SELECT ?q (COUNT(?q) as ?soma) WHERE {
      ?item wdt:P195 wd:Q56677470.
      ?item wdt:P170 ?q.
      FILTER NOT EXISTS { ?item wdt:P170 wd:Q4233718 }
    } 
    GROUP BY ?q ?qLabel
  } 
  OPTIONAL { ?q wdt:P19 ?nasc.
            ?nasc wdt:P625 ?coord. }
  OPTIONAL { ?q wdt:P18 ?img. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]". }
}
ORDER BY DESC (?soma)
LIMIT 1000

Experimente!

Linha do tempo mostrando a data de nascimento dos artistas do acervo

O código abaixo gera uma linha do tempo das datas de nascimento dos artistas que mais contribuíram com o acervo do Museu Paulista.

#defaultView:Timeline
# Show histogram of creators for all artworks that match GLAM entity
SELECT DISTINCT ?q ?qLabel ?soma ?nasc ?img WHERE
{
  {
    SELECT ?q (COUNT(?q) as ?soma) WHERE {
      ?item wdt:P195 wd:Q56677470.
      ?item wdt:P170 ?q.
      FILTER NOT EXISTS { ?item wdt:P170 wd:Q4233718 }
    }
    GROUP BY ?q ?qLabel
  }
  OPTIONAL { ?q wdt:P569 ?nasc }
  OPTIONAL { ?q wdt:P18 ?img }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]". }
}
ORDER BY DESC (?soma)
LIMIT 250

Experimente!